如何在 Excel 中统计 PDF 文件的页码?

ms exceladvanced excel functionmicrosoft technologies更新于 2024/12/30 15:08:17

如果您需要计算 PDF 文件中有多少页，并希望在 Excel 中轻松跟踪这些信息，那么您来对地方了。本文将教您如何使用 Excel 的强大功能快速高效地提取和记录 PDF 文件的页码。对于任何处理大量 PDF 文件的人来说，拥有一种快速自动化的页码统计方法都非常有帮助，无论他们是研究人员、专业人士还是学生。我们将使用 Excel 来自动执行此过程，而不是手动阅读每个 PDF 文件并统计页数。

本教程将引导您完成每个步骤，从设置 Excel 工作表和安装相应的软件，到从各种 PDF 文件中提取和存储页码。最后，您将拥有一个可以自动检索和更新 PDF 文档页数的 Excel 电子表格。那么，让我们开始学习如何使用 Excel 统计 PDF 文件中的页数吧。准备好简化您的流程并提高生产力吧!

计算 PDF 文件的页码

在这里，我们将首先插入一个 VBA 模块，然后运行它来完成任务。让我们通过一个简单的过程来学习如何在 Excel 中计算 PDF 文件的页码。

步骤 1

考虑任何 Excel 工作表。

首先，右键单击工作表名称，然后选择"查看代码"以打开 VBA 应用程序。

右键单击 >"查看代码"。

步骤 2

然后点击"插入"并选择"模块"，然后将以下代码复制到文本中。

插入 >"模块">"复制"。

代码

Sub Test()
   Dim I As Long
   Dim xRg As Range
   Dim xStr As String
   Dim xFd As FileDialog
   Dim xFdItem As Variant
   Dim xFileName As String
   Dim xFileNum As Long
   Dim RegExp As Object
   Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
   If xFd.Show = -1 Then
      xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
      xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
      Set xRg = Range("A1")
      Range("A:B").ClearContents
      Range("A1:B1").Font.Bold = True
      xRg = "File Name"
      xRg.Offset(0, 1) = "Pages"
      I = 2
      xStr = ""
      Do While xFileName <> ""
         Cells(I, 1) = xFileName
         Set RegExp = CreateObject("VBscript.RegExp")
         RegExp.Global = True
         RegExp.Pattern = "/Type\s*/Page[^s]"
         xFileNum = FreeFile
         Open (xFdItem & xFileName) For Binary As #xFileNum
            xStr = Space(LOF(xFileNum))
            Get #xFileNum, , xStr
         Close #xFileNum
         Cells(I, 2) = RegExp.Execute(xStr).Count
         I = I + 1
         xFileName = Dir
      Loop
      Columns("A:B").AutoFit
   End If
End Sub