如何在 Excel 中根据背景颜色删除行

ms exceladvanced excel functionmicrosoft technologies更新于 2024/9/25 11:56:17

Excel 是一款功能强大的电子表格程序，可让您轻松组织和分析数据。许多用户都面临根据特定条件删除行的需求。本课程将重点介绍如何根据单元格背景颜色删除行。当您拥有颜色编码的数据或希望根据美观程度筛选出特定行时，使用背景颜色会非常方便。与其手动滚动浏览电子表格并逐行删除行，不如介绍一种自动化方法，节省您的时间和精力。

在 Excel 中根据背景颜色删除行

在这里，我们将首先创建一个 VBA 模块，然后选择要删除的背景颜色单元格。让我们通过一个简单的过程来学习如何在 Excel 中根据背景颜色删除行。

步骤 1

假设有一个 Excel 工作表，其中包含具有多种背景颜色的单元格，如下图所示:

首先，右键单击工作表名称，然后选择"查看代码"以打开 VBA 应用程序。

右键单击 >查看代码。

步骤 2

然后点击"插入"，选择"模块"，并将以下代码复制到文本框中。

插入 > 模块 > 复制。

示例

Sub DeleteRows()
    Dim rngCl As Range
    Dim xRows As Long
    Dim xCol As Long
    Dim colorLg As Long
    On Error Resume Next
    Set rngCl = Application.InputBox _
        (Prompt:="Select a cell with the background color to be deleted", _
        Title:="Delete Based Color", Type:=8)
    On Error GoTo 0
    If rngCl Is Nothing Then
        MsgBox "User cancelled operation." & vbCrLf & _
        "Processing terminated", vbInformation, "Delete Rows Color"
        Exit Sub
    End If
    colorLg = rngCl.Interior.Color
    Application.ScreenUpdating = False
    With ActiveSheet.UsedRange
        For xRows = .Rows.Count To 1 Step -1
            For xCol = 1 To .Columns.Count
                           If .Cells(xRows, xCol).Interior.Color = colorLg Then
                    .Rows(xRows).Delete
                    Exit For
                End If
            Next xCol
        Next xRows
    End With
    Application.ScreenUpdating = True
End Sub

步骤 3

然后点击 F5 进入模块，选择要删除的背景颜色对应的单元格，然后点击"确定"即可删除所有背景颜色相同的单元格。

F5 > 选择单元格 > 确定。

注意:如果您只想删除单列中的单元格，请使用以下代码。

示例

Sub deleterow()
   Dim xRg As Range, rgDel As Range
    For Each xRg In ThisWorkbook.ActiveSheet.Range("A2:A10")
        If xRg.Interior.ColorIndex = 20 Then
            If rgDel Is Nothing Then
                Set rgDel = xRg
            Else
                Set rgDel = Union(rgDel, xRg)
            End If
        End If
    Next xRg
    If Not rgDel Is Nothing Then rgDel.EntireRow.Delete
End Sub

代码中，A2:A10 是列的范围。